变量
Nushell 的值可以使用 let、const 或 mut 关键字赋给命名变量。 创建变量后,我们可以使用 $ 后跟其名称来引用它。
变量类型
不可变变量
不可变变量在声明后不能更改其值。它们使用 let 关键字声明,
let val = 42
$val
# => 42
$val = 100
# => Error: nu::parser::assignment_requires_mutable_variable
# =>
# => × Assignment to an immutable variable.
# => ╭─[repl_entry #3:1:1]
# => 1 │ $val = 100
# => · ──┬─
# => · ╰── needs to be a mutable variable
# => ╰────
# => help: declare the variable with `mut`, or shadow it again with `let`然而,不可变变量可以被“遮蔽”。遮蔽意味着它们被重新声明,并且它们的初始值在同一作用域内不能再使用。
let val = 42 # 声明一个变量
do { let val = 101; $val } # 在内部作用域中,遮蔽该变量
# => 101
$val # 在外部作用域中,变量保持不变
# => 42
let val = $val + 1 # 现在,在外部作用域中,遮蔽原始变量
$val # 变量现在被遮蔽,其原始值不再可用
# => 43在管道中使用 let
let 也可以作为管道中的一步使用。在管道末尾,let <名称> 会把管道的结果存入变量, 同时也会把它输出出来:
[3 1 2] | sort | let nums
# => ╭───┬───╮
# => │ 0 │ 1 │
# => │ 1 │ 2 │
# => │ 2 │ 3 │
# => ╰───┴───╯
$nums | length
# => 3在管道中间,let 会保存它的输入,并原封不动地传给下一个命令:
"hello" | let greeting | str length
# => 5
$greeting
# => hello如果你不想在管道末尾看到这个值,加上 | ignore,或者改用常规的 let nums = ... 形式。
可变变量
可变变量允许通过赋值来更改其值。这些变量使用 mut 关键字声明。
mut val = 42
$val += 27
$val
# => 69有几个与可变变量一起使用的赋值运算符
| 运算符 | 描述 |
|---|---|
= | 为变量赋一个新值 |
+= | 将一个值加到变量上,并使和成为其新值 |
-= | 从变量中减去一个值,并使差成为其新值 |
*= | 将变量乘以一个值,并使积成为其新值 |
/= | 将变量除以一个值,并使商成为其新值 |
++= | 将列表、字符串或二进制值连接到变量 |
注意
+=、-=、*=和/=仅在其根操作预期工作的上下文中有效。例如,+=使用加法,因此不能用于加法通常会失败的上下文。结果还必须符合变量的类型:/总是产生float,因此当$x是int时$x /= 2会报错(请改用$x = $x // 2)。++=要求变量和值的类型相同:都是列表、都是字符串,或都是二进制值。要向列表追加单个元素,请使用$list ++= [$item]。
关于可变性的更多信息
闭包和嵌套的 def 不能从其环境中捕获可变变量。例如
# 计算列表中元素数量的朴素方法
mut x = 0
[1 2 3] | each { $x += 1 } # 错误:$x 在闭包中被捕获
# => Error: nu::parser::expected_keyword
# =>
# => × Capture of mutable variable.
# => ╭─[repl_entry #1:4:18]
# => 3 │
# => 4 │ [1 2 3] | each { $x += 1 } # error: $x is captured in a closure
# => · ─┬
# => · ╰── capture of mutable variable
# => ╰────要为此类行为使用可变变量,鼓励你使用循环
常量变量
常量变量是一个不可变变量,可以在解析时完全求值。这对于需要在解析时知道参数值的命令很有用,例如 source、use 和 plugin use。有关更深入的解释,请参阅 Nushell 代码如何运行。它们使用 const 关键字声明
const script_file = 'hello.nu'
source $script_file
# => Hello from hello.nu在可变和不可变变量之间进行选择
在大多数用例中,尽量使用不可变变量。
你可能想知道为什么 Nushell 默认使用不可变变量。在 Nushell 开发的最初几年,可变变量并不是一种语言特性。在 Nushell 开发的早期,我们决定看看在语言中使用更注重数据、函数式风格能走多远。当 Nushell 引入并行性时,这个实验显示了其价值。通过在任何 Nushell 脚本中从 each 切换到 par-each,你可以在输入上并行运行相应的代码块。这是可能的,因为 Nushell 的设计严重依赖于不可变性、组合和管道。
在 Nushell 中,许多(如果不是大多数)可变变量的用例都有一个函数式解决方案,该解决方案:
- 只使用不可变变量,因此...
- 具有更好的性能
- 支持流式处理
- 可以支持其他功能,例如上面提到的
par-each
例如,循环计数器是可变变量的常见模式,并且内置于大多数迭代命令中。例如,你可以使用 each 和 enumerate 来获取每个项目及其索引:
ls | enumerate | each { |elt| $"Item #($elt.index) is size ($elt.item.size)" }
# => ╭───┬─────────────────────────╮
# => │ 0 │ Item #0 is size 812 B │
# => │ 1 │ Item #1 is size 3.4 kB │
# => │ 2 │ Item #2 is size 28 B │
# => │ 3 │ Item #3 is size 11.2 kB │
# => ╰───┴─────────────────────────╯你还可以使用 reduce 命令以与在循环中改变变量相同的方式工作。例如,如果你想在字符串列表中找到最长的字符串,你可以这样做:
[one, two, three, four, five, six] | reduce {|current_item, max|
if ($current_item | str length) > ($max | str length) {
$current_item
} else {
$max
}
}
# => three虽然 reduce 处理列表,但 generate 命令可以与任意源一起使用,例如外部 REST API,也无需可变变量。这是一个示例,它每小时检索一次本地天气数据,并从该数据生成一个连续的列表。each 命令可用于在每个新列表项可用时使用它。
generate {|weather_station|
let res = try {
http get -ef $'https://api.weather.gov/stations/($weather_station)/observations/latest'
} catch {
null
}
sleep 1hr
match $res {
null => {
next: $weather_station
}
_ => {
out: ($res.body? | default '' | from json)
next: $weather_station
}
}
} khot
| each {|weather_report|
{
time: ($weather_report.properties.timestamp | into datetime)
temp: $weather_report.properties.temperature.value
}
}性能考虑
使用带有不可变变量的过滤器命令通常比使用带有传统流控制语句(如 for 和 while)的可变变量性能要好得多。例如:
使用
for语句创建包含 10,000 个随机数的列表:timeit { mut randoms = [] for _ in 1..10_000 { $randoms = ($randoms | append (random int)) } }结果:1分 4秒 191毫秒 135微秒 90纳秒
使用
each执行相同的操作:timeit { let randoms = (1..10_000 | each {random int}) }结果:10ms 449µs 500ns
使用
each进行 10,000,000 次迭代:timeit { let randoms = (1..1_000_000 | each {random int}) }结果:1sec 47ms 554µs 250ns
与许多过滤器一样,
each语句也流式传输其结果,这意味着管道的下一阶段可以继续处理,而无需等待结果被收集到变量中。对于可以通过并行化优化的任务,如上所述,
par-each可以获得更显着的性能提升。
删除变量
变量的生命周期通常持续到声明它的作用域结束。要提前释放一个变量(例如它持有大量数据), 可以用 unlet 删除它。之后该变量就不能再使用了:
let a = 1
let b = 2
unlet $a $b
$a
# => Error: nu::shell::variable_not_found
# =>
# => × Variable not found
# => ╭─[repl_entry #1:4:1]
# => 3 │ unlet $a $b
# => 4 │ $a
# => · ─┬
# => · ╰── variable not found
# => ╰────变量名
Nushell 中的变量名对其可以包含的字符有一些限制。特别是,它们不能包含这些字符:
. [ ( { + - * ^ / = ! < > & |一些脚本声明以 $ 开头的变量是很常见的。这是允许的,它等同于根本没有 $。
let $var = 42
# 与 `let var = 42` 相同